options nocenter nodate;
/*

Table 4. Total sample size required to achieve 95% power in cross-over 
thorough QT studies with all-male, all-female and mixed populations,
in the case of a single post-dose time point using Fridericia-corrected 
QT interval. 

Subject population: Males.

*/
data parameters;
    delta=5; * True mean difference (msec);
    r=3; * Number of replicates;
    beta=0.05; * Type II error rate;
    * Variance components for the selected subject population (males);    
    sr=5.5**2; * Error term;
    ssd=3.6**2; * Subject-by-day term;
    ssdt=2.9**2; * Subject-by-time and subject-by-day-by-time;    
    * Variance of the treatment difference;
    * Definition A1;
    sigmasq=2*(sr/r+ssd+ssdt); 
    definition="Definition A1";
    output;
    * Definition A2;
    sigmasq=4*(sr/r+ssdt); 
    definition="Definition A2";
    output;
    * Definition B1;
    sigmasq=4*(sr/r+ssd+ssdt); 
    definition="Definition B1";
    output;
    * Definition B2;
    sigmasq=8*(sr/r+ssdt); 
    definition="Definition B2";
    output;
data samplesize;
    set parameters; 
    num=(probit(0.95)+probit(1-beta))*sqrt(sigmasq); 
    den=10-delta;    
    n=ceil((num/den)**2); * Total sample size;
proc print data=samplesize noobs;
    var definition n;
    run;